cd5439fb97
libevent is a shared dependency between cam and lc-compliance, move it to src/apps/. The shared dependency will be used to condition compilation of source files in an upcoming application static library. Signed-off-by: Laurent Pinchart <laurent.pinchart@ideasonboard.com> Reviewed-by: Paul Elder <paul.elder@ideasonboard.com> Reviewed-by: Kieran Bingham <kieran.bingham@ideasonboard.com>
73 lines
1.6 KiB
Meson
73 lines
1.6 KiB
Meson
# SPDX-License-Identifier: CC0-1.0
|
|
|
|
if opt_cam.disabled() or not libevent.found()
|
|
cam_enabled = false
|
|
subdir_done()
|
|
endif
|
|
|
|
cam_enabled = true
|
|
|
|
cam_sources = files([
|
|
'camera_session.cpp',
|
|
'capture_script.cpp',
|
|
'event_loop.cpp',
|
|
'file_sink.cpp',
|
|
'frame_sink.cpp',
|
|
'image.cpp',
|
|
'main.cpp',
|
|
'options.cpp',
|
|
'stream_options.cpp',
|
|
])
|
|
|
|
cam_cpp_args = []
|
|
|
|
libdrm = dependency('libdrm', required : false)
|
|
libjpeg = dependency('libjpeg', required : false)
|
|
libsdl2 = dependency('SDL2', required : false)
|
|
libtiff = dependency('libtiff-4', required : false)
|
|
|
|
if libdrm.found()
|
|
cam_cpp_args += [ '-DHAVE_KMS' ]
|
|
cam_sources += files([
|
|
'drm.cpp',
|
|
'kms_sink.cpp'
|
|
])
|
|
endif
|
|
|
|
if libsdl2.found()
|
|
cam_cpp_args += ['-DHAVE_SDL']
|
|
cam_sources += files([
|
|
'sdl_sink.cpp',
|
|
'sdl_texture.cpp',
|
|
'sdl_texture_yuv.cpp',
|
|
])
|
|
|
|
if libjpeg.found()
|
|
cam_cpp_args += ['-DHAVE_LIBJPEG']
|
|
cam_sources += files([
|
|
'sdl_texture_mjpg.cpp'
|
|
])
|
|
endif
|
|
endif
|
|
|
|
if libtiff.found()
|
|
cam_cpp_args += ['-DHAVE_TIFF']
|
|
cam_sources += files([
|
|
'dng_writer.cpp',
|
|
])
|
|
endif
|
|
|
|
cam = executable('cam', cam_sources,
|
|
dependencies : [
|
|
libatomic,
|
|
libcamera_public,
|
|
libdrm,
|
|
libevent,
|
|
libjpeg,
|
|
libsdl2,
|
|
libtiff,
|
|
libyaml,
|
|
],
|
|
cpp_args : cam_cpp_args,
|
|
install : true)
|